Cara menggunakan fungsi Excel VLOOKUP -

Ringkasan

VLOOKUP adalah fungsi Excel untuk mencari data dalam jadual yang disusun secara menegak. VLOOKUP menyokong pemadanan yang hampir tepat dan tepat, dan wildcard (*?) Untuk pertandingan separa. Nilai carian mesti muncul di lajur pertama jadual yang dimasukkan ke dalam VLOOKUP.

Tujuan

Cari nilai dalam jadual dengan memadankan pada lajur pertama

Nilai pulangan

Nilai yang sepadan dari jadual.

Sintaks

= VLOOKUP (nilai, jadual, col_index, (range_lookup))

Hujah

nilai - Nilai yang perlu dicari di lajur pertama jadual.
table - Jadual dari mana untuk mendapatkan nilai.
col_index - Lajur dalam jadual dari mana untuk mendapatkan nilai.
range_lookup - (pilihan) BENAR = padanan anggaran (lalai). SALAH = padanan tepat.

Versi

Excel 2003

Catatan penggunaan

VLOOKUP adalah fungsi Excel untuk mendapatkan data dari jadual yang disusun secara menegak. Nilai carian mesti muncul di lajur pertama jadual yang dimasukkan ke dalam VLOOKUP. VLOOKUP menyokong pemadanan yang hampir tepat dan tepat, dan wildcard (*?) Untuk pertandingan separa.

V adalah untuk menegak

Tujuan VLOOKUP adalah untuk mendapatkan maklumat dari jadual yang disusun seperti ini:

Menggunakan nombor Pesanan di lajur B sebagai nilai pencarian, VLOOKUP dapat memperoleh ID Pelanggan, Jumlah, Nama, dan Negeri untuk sebarang pesanan. Sebagai contoh, untuk mendapatkan nama pelanggan untuk pesanan 1004, formula adalah:

=VLOOKUP(1004,B5:F9,4,FALSE) // returns "Sue Martin"

Untuk data mendatar, anda boleh menggunakan HLOOKUP, INDEX dan MATCH, atau XLOOKUP.

VLOOKUP berdasarkan nombor lajur

Apabila anda menggunakan VLOOKUP, bayangkan bahawa setiap lajur dalam jadual diberi nombor, bermula dari sebelah kiri. Untuk mendapatkan nilai dari lajur tertentu, berikan nombor yang sesuai sebagai "indeks lajur". Contohnya, indeks lajur untuk mendapatkan nama pertama di bawah adalah 2:

Nama belakang dan e-mel boleh diambil dengan lajur 3 dan 4:

=VLOOKUP(H3,B4:E13,2,FALSE) // first name =VLOOKUP(H3,B4:E13,3,FALSE) // last name =VLOOKUP(H3,B4:E13,4,FALSE) // email address

VLOOKUP hanya kelihatan betul

VLOOKUP hanya dapat melihat ke kanan. Data yang anda ingin dapatkan (nilai hasil) dapat muncul di lajur mana pun di sebelah kanan nilai pencarian:

Sekiranya anda perlu mencari nilai di sebelah kiri, lihat INDEX dan MATCH, atau XLOOKUP.

Pencocokan tepat dan tepat

VLOOKUP mempunyai dua mod pemadanan, tepat dan hampir. Nama argumen yang mengawal pencocokan adalah " range_lookup ". Ini adalah nama yang membingungkan, kerana nampaknya ada kaitan dengan julat sel seperti A1: A10. Sebenarnya, kata "rentang" dalam hal ini merujuk pada "rentang nilai" - apabila range_lookup adalah BENAR, VLOOKUP akan memadankan julat nilai dan bukan nilai yang tepat. Contoh yang baik ialah menggunakan VLOOKUP untuk mengira nilai.

Penting untuk memahami bahawa range_lookup lalai menjadi BENAR, yang bermaksud VLOOKUP akan menggunakan pemadanan anggaran secara lalai, yang boleh membahayakan. Tetapkan range_lookup ke FALSE untuk memaksa pencocokan tepat:

=VLOOKUP(value, table, col_index) // approximate match (default) =VLOOKUP(value, table, col_index, TRUE) // approximate match =VLOOKUP(value, table, col_index, FALSE) // exact match

Catatan: Anda juga boleh memberikan sifar (0) dan bukannya SALAH untuk pertandingan yang tepat.

Pertandingan tepat

Dalam kebanyakan kes, anda mungkin mahu menggunakan VLOOKUP dalam mod padanan tepat. Ini masuk akal apabila anda mempunyai kunci unik untuk digunakan sebagai nilai pencarian, misalnya, tajuk filem dalam data ini:

Rumus dalam H6 untuk mencari Tahun , berdasarkan padanan judul filem yang tepat, adalah:

=VLOOKUP(H4,B5:E9,2,FALSE) // FALSE = exact match

Padanan anggaran

In cases when you want the best match , not necessarily an exact match , you'll want to use approximate mode. For example, below we want to look up a commission rate in the table G5:H10. The lookup values come from column C. In this example, we need to use VLOOKUP in approximate match mode, because in most cases an exact match will never be found. The VLOOKUP formula in D5 is configured to perform an approximate match by setting the last argument to TRUE:

=VLOOKUP(C5,$G$5:$H$10,2,TRUE) // TRUE = approximate match

VLOOKUP will scan values in column G for the lookup value. If an exact match is found, VLOOKUP will use it. If not, VLOOKUP will "step back" and match the previous row.

Note: data must be sorted in ascending order by lookup value when you use approximate match mode with VLOOKUP.

First match

In the case of duplicate values, VLOOKUP will find the first match when the match mode is exact. In screen below, VLOOKUP is configured to find the price for the color "Green". There are three entries with the color Green, and VLOOKUP returns the price for the first entry, $17. The formula in cell F5 is:

=VLOOKUP(E5,B5:C11,2,FALSE) // returns 17

Wildcard match

The VLOOKUP function supports wildcards, which makes it possible to perform a partial match on a lookup value. For instance, you can use VLOOKUP to retrieve values from a table after typing in only part of a lookup value. To use wildcards with VLOOKUP, you must specify exact match mode by providing FALSE or 0 for the last argument, range_lookup . The formula in H7 retrieves the first name, "Michael", after typing "Aya" into cell H4:

=VLOOKUP($H$4&"*",$B$5:$E$104,2,FALSE)

Read a more detailed explanation here.

Two-way lookup

Inside the VLOOKUP function, the column index argument is normally hard-coded as a static number. However, you can also create a dynamic column index by using the MATCH function to locate the right column. This technique allows you to create a dynamic two-way lookup, matching on both rows and columns. In the screen below, VLOOKUP is configured to perform a lookup based on Name and Month. The formula in H6 is:

=VLOOKUP(H4,B5:E13,MATCH(H5,B4:E4,0),0)

For more details, see this example.

Note: In general, INDEX and MATCH is a more flexible way to perform two-way lookups.

Multiple criteria

The VLOOKUP function does not handle multiple criteria natively. However, you can use a helper column to join multiple fields together, and use these fields like multiple criteria inside VLOOKUP. In the example below, Column B is a helper column that concatenates first and last names together with this formula:

=C5&D5 // helper column

VLOOKUP is configured to do the the same thing to create a lookup value. The formula in H6 is:

=VLOOKUP(H4&H5,B5:E13,4,0)

For details, see this example.

Note: INDEX and MATCH and XLOOKUP are more robust ways to handle lookups based on multiple criteria.

VLOOKUP and #N/A errors

If you use VLOOKUP you will inevitably run into the #N/A error. The #N/A error just means "not found". For example, in the screen below, the lookup value "Toy Story 2" does not exist in the lookup table, and all three VLOOKUP formulas return #N/A:

One way to "trap" the NA error is to use the IFNA function like this:

The formula in H6 is:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"Not found")

The message can be customized as desired. To return nothing (i.e. to display a blank result) when VLOOKUP returns #N/A you can use an empty string like this:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"") // no message

The #N/A error is useful because it tells you something is wrong. In practice, there are many reasons why you might see this error, including:

The lookup value does not exist in the table
The lookup value is misspelled, or contains extra space
Match mode is exact, but should be approximate
The table range is not entered correctly
You are copying VLOOKUP, and the table reference is not locked

More about VLOOKUP

More VLOOKUP examples
VLOOKUP videos
23 tips for using VLOOKUP

Other notes

Range_lookup controls whether value needs to match exactly or not. The default is TRUE = allow non-exact match.
Set range_lookup to FALSE to require an exact match and TRUE to allow a non-exact match .
If range_lookup is TRUE (the default setting), a non-exact match will cause the VLOOKUP function to match the nearest value in the table that is still less than value .
When range_lookup is omitted, the VLOOKUP function will allow a non-exact match, but it will use an exact match if one exists.
If range_lookup is TRUE (the default setting) make sure that lookup values in the first row of the table are sorted in ascending order. Otherwise, VLOOKUP may return an incorrect or unexpected value.
If range_lookup is FALSE (require exact match), values in the first column of table do not need to be sorted.